1С 8.3 БСП ДополнитьСтроку

Данные > 1С 8.3 БСП > Строковые функции

ПРИМЕРЫ КОДА 1С

Перейти в раздел примеры кода 1С 8.3:

1С 8.3 БСП ДополнитьСтроку: дополняет строку символами слева или справа до заданной длины и возвращает ее. При этом удаляются незначащие символы слева и справа (подробнее про незначащие символы

см. синтакс-помощник к методу платформы СокрЛП). По умолчанию функция дополняет строку символами "0" (ноль) слева..

Официальная документация ИТС по функционалу

Примера кода

// Дополняет строку символами слева или справа до заданной длины и возвращает ее.
// При этом удаляются незначащие символы слева и справа (подробнее про незначащие символы
// см. синтакс-помощник к методу платформы СокрЛП).
// По умолчанию функция дополняет строку символами "0" (ноль) слева.
//
// Параметры:
// Значение    - Строка - исходная строка, которую необходимо дополнить символами;
// ДлинаСтроки - Число - требуемая результирующая длина строки;
// Символ      - Строка - символ, которым необходимо дополнить строку;
// Режим       - Строка - "Слева" или "Справа" - вариант добавления символов к исходной строке.
//
// Возвращаемое значение:
// Строка - строка, дополненная символами.
//
// Пример:
// 1. Результат = СтроковыеФункцииКлиентСервер.ДополнитьСтроку("1234", 10, "0", "Слева");
// Возвращает: "0000001234".
//
// 2. Результат = СтроковыеФункцииКлиентСервер.ДополнитьСтроку(" 1234 ", 10, "#", "Справа");
// Строка = " 1234 "; ДлинаСтроки = 10; Символ = "#"; Режим = "Справа"
// Возвращает: "1234######".
//
Функция ДополнитьСтроку(Знач Значение, Знач ДлинаСтроки, Знач Символ = "0", Знач Режим = "Слева") Экспорт

   // Длина символа не должна превышать единицы.
   Символ = Лев(Символ, 1);

   // Удаляем крайние пробелы слева и справа строки.
   Значение = СокрЛП(Значение);
   КоличествоСимволовНадоДобавить = ДлинаСтроки - СтрДлина(Значение);

   Если КоличествоСимволовНадоДобавить > 0 Тогда

       СтрокаДляДобавления = СформироватьСтрокуСимволов(Символ, КоличествоСимволовНадоДобавить);
       Если ВРег(Режим) = "СЛЕВА" Тогда
           Значение = СтрокаДляДобавления + Значение;
       ИначеЕсли ВРег(Режим) = "СПРАВА" Тогда
           Значение = Значение + СтрокаДляДобавления;
       КонецЕсли;

   КонецЕсли;

   Возврат Значение;

КонецФункции

// Типовая конфигурация Библиотека стандартных подсистем (далее - БСП)
// Код БСП распространяется по лицензии Attribution 4.0 International (CC BY 4.0):
// ссылка на лицензию: https://creativecommons.org/licenses/by/4.0/legalcode

комментарии

____________________

Перепечатка текста и фотографий разрешена при наличии прямой ссылки на источник