1С 8.3 БСП ПараметрыГенерацииШтрихкода - Программист 1С Минск. Автоматизация бизнеса.

Популярные страницы:
Перейти к контенту

1С 8.3 БСП ПараметрыГенерацииШтрихкода

Данные > Примеры кода 1С > 1С 8.3 БСП > Генерация штрих-кода
Перейти в раздел примеры кода 1С 8.3:
1С 8.3 БСП ПараметрыГенерацииШтрихкода. Пустая структура для заполнения параметра "ПараметрыШтрихкода" используемого для получения изображения штрих кода.
Примера кода от rayastar
Результат = ГенерацияШтрихкода.ПараметрыГенерацииШтрихкода();

//
Функция ДанныеQRКода(QRСтрока, УровеньКоррекции, Размер) Экспорт

   ПараметрыШтрихкода = ГенерацияШтрихкода.ПараметрыГенерацииШтрихкода();

   ПараметрыШтрихкода.Ширина = Размер;
   ПараметрыШтрихкода.Высота = Размер;
   ПараметрыШтрихкода.Штрихкод = QRСтрока;
   ПараметрыШтрихкода.УровеньКоррекцииQR = УровеньКоррекции;
   ПараметрыШтрихкода.ТипКода = 16; // QR
   ПараметрыШтрихкода.УбратьЛишнийФон = Истина;

   Попытка
       РезультатФормированияШтрихкода = ИзображениеШтрихкода(ПараметрыШтрихкода);
       ДвоичныеДанныеКартинки = РезультатФормированияШтрихкода.ДвоичныеДанные;
   Исключение
       ТекстОшибки = НСтр("ru = 'Ошибка формирование QR-кода'");
       ЗаписьЖурналаРегистрации(ТекстОшибки, УровеньЖурналаРегистрации.Ошибка, , ,
           ПодробноеПредставлениеОшибки(ИнформацияОбОшибке()));
   КонецПопытки;

   Возврат ДвоичныеДанныеКартинки;

КонецФункции
// Автор библиотеки: ООО "1С-Софт". Все права защищены © 2021
// Типовая конфигурация Библиотека стандартных подсистем (далее - БСП)
// Код БСП распространяется по лицензии Attribution 4.0 International (CC BY 4.0):
// ссылка на лицензию: https://creativecommons.org/licenses/by/4.0/legalcode
Метод БСП
// Пустая структура для заполнения параметра "ПараметрыШтрихкода" используемого для получения изображения штрих кода.
//
// Возвращаемое значение:
//   Структура:
//   * Ширина - Число - ширина изображения штрих кода.
//   * Высота - Число - высота изображения штрих кода.
//   * ТипКода - Число - штрихкода.
//       Возможные значение:
//      99 -  Авто выбор
//      0 - EAN8
//      1 - EAN13
//      2 - EAN128
//      3 - Code39
//      4 - Code128
//      5 - Code16k
//      6 - PDF417
//      7 - Standart (Industrial) 2 of 5
//      8 - Interleaved 2 of 5
//      9 - Code39 Расширение
//      10 - Code93
//      11 - ITF14
//      12 - RSS14
//      14 - EAN13AddOn2
//      15 - EAN13AddOn5
//      16 - QR
//      17 - GS1DataBarExpandedStacked
//      18 - Datamatrix ASCII
//      19 - Datamatrix BASE256
//      20 - Datamatrix TEXT
//      21 - Datamatrix C40
//      22 - Datamatrix X12
//      23 - Datamatrix EDIFACT
//      24 - Datamatrix GS1ASCII:
//   * ОтображатьТекст - Булево - отображать HRI теста для штрихкода.
//   * РазмерШрифта - Число - размер шрифта HRI теста для штрихкода.
//   * УголПоворота - Число - угол поворота.
//      Возможные значения: 0, 90, 180, 270.
//   * Штрихкод - Строка - значение штрихкод в виде строки или Base64.
//   * ТипВходныхДанных - Число - тип входных данных
//      Возможные значения: 0 - Строка, 1 - Base64
//   * ПрозрачныйФон - Булево - прозрачный фон изображения штрихкода.
//   * УровеньКоррекцииQR - Число - уровень коррекции штрихкода QR.
//      Возможные значения: 0 - L, 1 - M, 2 - Q, 3 - H.
//   * Масштабировать - Булево -  масштабировать изображение штрихкода.
//   * СохранятьПропорции - Булево - сохранять пропорции изображения штрихкода.
//   * ВертикальноеВыравнивание - Число - вертикальное выравнивание штрихкода.
//      Возможные значения: 1 - По верхнему краю, 2 - По центру, 3 - По нижнему краю
//   * GS1DatabarКоличествоСтрок - Число - количество строк в штрихкоде GS1Databar.
//   * УбратьЛишнийФон - Булево
//   * ЛоготипКартинка - Строка - строка с base64 представлением png картинки логотипа.
//   * ЛоготипРазмерПроцентОтШК - Число - процент от генерированного QR для вписывания логотипа.
//
Функция ПараметрыГенерацииШтрихкода() Экспорт

   ПараметрыШтрихкода = Новый Структура;
   ПараметрыШтрихкода.Вставить("Ширина"            , 100);
   ПараметрыШтрихкода.Вставить("Высота"            , 100);
   ПараметрыШтрихкода.Вставить("ТипКода"           , 99);
   ПараметрыШтрихкода.Вставить("ОтображатьТекст"   , Истина);
   ПараметрыШтрихкода.Вставить("РазмерШрифта"      , 12);
   ПараметрыШтрихкода.Вставить("УголПоворота"      , 0);
   ПараметрыШтрихкода.Вставить("Штрихкод"          , "");
   ПараметрыШтрихкода.Вставить("ПрозрачныйФон"     , Истина);
   ПараметрыШтрихкода.Вставить("УровеньКоррекцииQR", 1);
   ПараметрыШтрихкода.Вставить("Масштабировать"           , Ложь);
   ПараметрыШтрихкода.Вставить("СохранятьПропорции"       , Ложь);
   ПараметрыШтрихкода.Вставить("ВертикальноеВыравнивание" , 1);
   ПараметрыШтрихкода.Вставить("GS1DatabarКоличествоСтрок", 2);
   ПараметрыШтрихкода.Вставить("ТипВходныхДанных", 0);
   ПараметрыШтрихкода.Вставить("УбратьЛишнийФон" , Ложь);
   ПараметрыШтрихкода.Вставить("ЛоготипКартинка");
   ПараметрыШтрихкода.Вставить("ЛоготипРазмерПроцентОтШК");

   Возврат ПараметрыШтрихкода;

КонецФункции
// Автор библиотеки: ООО "1С-Софт". Все права защищены © 2021
// Типовая конфигурация Библиотека стандартных подсистем (далее - БСП)
// Код БСП распространяется по лицензии Attribution 4.0 International (CC BY 4.0):
// ссылка на лицензию: https://creativecommons.org/licenses/by/4.0/legalcode
Поиск кода
0
Комментарии
____________________
Copyright©, «Программист 1С в г.Минске», 31.08.2021
Перепечатка текста и фотографий разрешена при наличии прямой ссылки на источник
Назад к содержимому