1С 8.3 Это ошибка существования метода

Данные > Примеры кода 1С > 1С 8.3 Описание типов

ПРИМЕРЫ КОДА 1С

Перейти в раздел примеры кода 1С 8.3:

Это ошибка существования метода в 1С 8.3:

// Это ошибка существования метода.
// Источник: https://github.com/SeiOkami/CollectionMethodsOneS/issues/158
//
// Параметры:
// ИнформацияОбОшибке - ИнформацияОбОшибке
// ИмяМетода - Строка
// ПроверятьНаНеобъектныйТип - Булево - Если Истина, то ошибка "Значение не является объектного типа" тоже считается за ошибку отстуствия типа
//
// Возвращаемое значение:
// Булево
//
// Пример:
//
// Попытка
//      Объект.НеобязательныйМетод();
// Исключение
//      Если НЕ ЭтоОшибкаСуществованияМетода(ИнформацияОбОшибке(), "НеобязательныйМетод") Тогда
//          ВызватьИсключение;
//      КонецЕсли;
// КонецПопытки;
//
Функция ЭтоОшибкаСуществованияМетода(ИнформацияОбОшибке,
   ИмяМетода, ПроверятьНаНеобъектныйТип = Истина) Экспорт

   ОписаниеОшибки = ИнформацияОбОшибке.Описание;

   ВременныеОбъекты = Новый Массив; //Массив из Неопределено
   ВременныеОбъекты.Добавить(Новый Структура);

   Если ПроверятьНаНеобъектныйТип Тогда
       ВременныеОбъекты.Добавить();
   КонецЕсли;

   Для Каждого ВременныйОбъект Из ВременныеОбъекты Цикл

       Попытка
           ВременныйОбъект.СуперПуперМетод(); //@skip-check dynamic-access-method-not-found
       Исключение
           ВременноеОписание = СтрЗаменить(ИнформацияОбОшибке().Описание, "СуперПуперМетод", ИмяМетода);
           Если ОписаниеОшибки = ВременноеОписание Тогда
               Возврат Истина;
           КонецЕсли;
       КонецПопытки;

   КонецЦикла;

   Возврат Ложь;

КонецФункции

// MIT License

// Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated documentation files

// (the "Software"), to deal in the Software without restriction, including without limitation the rights to use, copy, modify,

// merge, publish, distribute, sublicense, and/or sell copies of the Software, and to permit persons to whom the Software is

// furnished to do so, subject to the following conditions:

// The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.

комментарии

____________________

Перепечатка текста и фотографий разрешена при наличии прямой ссылки на источник